在 Excel 中，CountA函數(shù)用于統(tǒng)計(jì)除空單元外各種單元格的個(gè)數(shù)，它與Count函數(shù)的區(qū)別是，CountA統(tǒng)計(jì)為文本和邏輯值的單元格，而Count函數(shù)不統(tǒng)計(jì)。CountBlank函數(shù)專用于統(tǒng)計(jì)空單元格的個(gè)數(shù)，包括公式返回的空單元格。

如果不統(tǒng)計(jì) 0 和公式返回空值的單元格，可以用 CountA + CountBlank + CountIf 組合實(shí)現(xiàn)；如果要實(shí)現(xiàn)添加數(shù)據(jù)后自動(dòng)求和，可以用 OffSet + CountA函數(shù)組合；如果要實(shí)現(xiàn)分段統(tǒng)計(jì)，可以用 If + Mod + CountA + Row函數(shù)組合。

一、Excel CountA函數(shù)與CountBlank函數(shù)的語(yǔ)法

（一）CountA函數(shù)

1、表達(dá)式：COUNTA(Value1, [Value2], ...)

中文表達(dá)式：CountA(值1, [值2], ...)

2、說(shuō)明：

A、CountA函數(shù)統(tǒng)計(jì)數(shù)字、日期、文本、邏輯值（True 和 False)、空值（如公式返回的空值""）和錯(cuò)誤值，它們可以是單元格或數(shù)組；而Count函數(shù)只統(tǒng)計(jì)數(shù)字、日期和能轉(zhuǎn)為數(shù)字的單元格。

B、CountA函數(shù)至少要有一個(gè) Value 參數(shù)，最多只能有 255 個(gè) Value 參數(shù)。

（二）CountBlank函數(shù)

1、表達(dá)式：COUNTBLANK(Range)

中文表達(dá)式：COUNTBLANK(范圍)

2、說(shuō)明：

A、CountBlank函數(shù)統(tǒng)計(jì)空單元格、空文本（即""），不統(tǒng)計(jì)有 0 值的單元格。

B、運(yùn)行CountBlank函數(shù)，需要關(guān)閉迭代計(jì)算，方法為：依次選擇“文件”→ 選項(xiàng) → 公式 → “計(jì)算選項(xiàng)”下 → 不勾選“啟用迭代計(jì)算”→ 確定。

二、Excel CountA函數(shù)的使用方法及實(shí)例

（一）統(tǒng)計(jì)既有文本又有數(shù)字單元格區(qū)域的實(shí)例

1、雙擊 D8 單元格，輸入公式 =COUNTA(D1:D7)，按回車，返回統(tǒng)計(jì)結(jié)果 7；操作過(guò)程步驟，如圖1所示：

圖1

2、D1 至 D7 中有一個(gè)文本單元格和 6 個(gè)數(shù)字單元格，統(tǒng)計(jì)結(jié)果為 7，說(shuō)明文本和數(shù)字都統(tǒng)計(jì)了。

（二）統(tǒng)計(jì)空值和錯(cuò)誤值、不統(tǒng)計(jì)空單元格的實(shí)例

1、雙擊 A4 單元格，把公式 =COUNTA(A1:A3) 復(fù)制到 A4，按回車，返回統(tǒng)計(jì)結(jié)果 2；雙擊 A1，里面什么都沒(méi)有為空單元格；雙擊 A2，里面是一個(gè) If 公式返回空值；再雙擊 A1，輸入 5，統(tǒng)計(jì)結(jié)果變?yōu)?3；操作過(guò)程步驟，如圖2所示：

圖2

2、當(dāng) A1 為空時(shí)，統(tǒng)計(jì)結(jié)果為 2，當(dāng) A1 輸入 5 后，統(tǒng)計(jì)結(jié)果為 3，說(shuō)明空單元格不統(tǒng)計(jì)，但公式返回的空值統(tǒng)計(jì)。

（三）統(tǒng)計(jì)一行不為空的單元格總數(shù)實(shí)例

1、統(tǒng)計(jì)第一行不為空的單元格總數(shù)。雙擊 A8 單元格，把公式 =COUNTA(1:1) 復(fù)制到 A8，按回車，返回統(tǒng)計(jì)結(jié)果 4；再次雙擊 A8，在兩個(gè) 1 前都添加 $，按回車，也返回 4；操作過(guò)程步驟，如圖3所示：

圖3

2、公式說(shuō)明：

公式 =COUNTA(1:1) 中的 1:1 表示引用第一行；=COUNTA($1:$1) 中的 $1:$1 也表示引用第一行，所不同的是 1:1 是相對(duì)引用，而 $1:$1 是絕對(duì)引用；如果公式要往下拖且要求拖到第幾行統(tǒng)計(jì)該行的單元格總數(shù)，則應(yīng)該使用 =COUNTA(1:1)，因?yàn)橥�下拖時(shí)，1:1 會(huì)變?yōu)?2:2，3:3 等。

提示：公式 =COUNTA(1:1) 和 =COUNTA($1:$1) 不能寫(xiě)到第一行，否則無(wú)法統(tǒng)計(jì)出正確的結(jié)果。

（四）統(tǒng)計(jì)一列不為空的單元格總數(shù)實(shí)例

1、統(tǒng)計(jì)第一列不為空的單元格總數(shù)。雙擊 B8 單元格，把公式 =COUNTA(A:A) 復(fù)制到 B8，按回車，返回統(tǒng)計(jì)結(jié)果 7；再雙擊 B8，在兩個(gè)A 前都加 $，按回車，同樣返回 7；操作過(guò)程步驟，如圖4所示：

圖4

2、公式 =COUNTA(A:A) 中 A:A 表示對(duì) A 列的引用，=COUNTA($A:$A) 也表示對(duì) A 列的引用；A:A 與 $A:$A 區(qū)別也是前者為相對(duì)引用后者為絕對(duì)引用；另外，公式也不能寫(xiě)到 A 列，否則也會(huì)返回不正確的值。

（五）跨表統(tǒng)計(jì)實(shí)例

1、假如要統(tǒng)計(jì)“水果銷量表1和水果銷量表2”中的 B2:B7 的單元格總數(shù)。當(dāng)前在“水果銷量表1”，單擊“水果銷量表2”標(biāo)簽切掉到該工作簿，雙擊 A8 單元格，把公式 =COUNTA(水果銷量表1:水果銷量表2!B2:B7) 復(fù)制到 A8，按回車，返回統(tǒng)計(jì)結(jié)果 12；操作過(guò)程步驟，如圖5所示：

圖5

2、公式說(shuō)明：

公式 =COUNTA(水果銷量表1:水果銷量表2!B2:B7) 中“水果銷量表1:水果銷量表2”表示引用兩個(gè)工作簿，! 用于工作簿與引用單元格之間作為分隔符，引用兩個(gè)工作簿單元格區(qū)域相同時(shí)，可以把工作簿寫(xiě)在一起，否則要把工作簿分開(kāi)寫(xiě)。

三、Excel CountBlank函數(shù)的使用方法及實(shí)例

（一）統(tǒng)計(jì)所有空單元格實(shí)例

1、雙擊 A5 單元格，把公式 =COUNTBLANK(A1:A4) 復(fù)制到 A5，按回車，返回統(tǒng)計(jì)結(jié)果 2；雙擊 A1，里有一個(gè) If 返回空值 "" 公式，再雙擊 A3，是一個(gè)空單元格；操作過(guò)程步驟，如圖6所示：

圖6

2、A1:A4 有兩個(gè)空單元格，一個(gè)是公式返回的空值單元格，另一個(gè)是沒(méi)有輸入任何文字的空單元，兩個(gè)都被統(tǒng)計(jì)了，說(shuō)明CountBlank函數(shù)都統(tǒng)計(jì)它們。

（二）CountA + CountBlank + CountIf函數(shù)組合實(shí)現(xiàn)不統(tǒng)計(jì) 0 和公式返回空值的單元格實(shí)例

1、雙擊 A5 單元格，把公式 =COUNTA(A1:A4)-COUNTBLANK(A1:A4)-COUNTIF(A1:A4,"=0") 復(fù)制到 A5，按回車，返回統(tǒng)計(jì)結(jié)果 2；雙擊 A1 單元格，里面是一個(gè)返回空值 "" 的 If 公式；操作過(guò)程步驟，如圖7所示：

圖7

2、公式 =COUNTA(A1:A4)-COUNTBLANK(A1:A4)-COUNTIF(A1:A4,"=0") 說(shuō)明：

=COUNTA(A1:A4) 用于統(tǒng)計(jì) A1:A4 中包含文本、數(shù)值、空單元格的個(gè)數(shù)，結(jié)果為 4；COUNTBLANK(A1:A4) 用于統(tǒng)計(jì) A1:A4 中空單元格的個(gè)數(shù)，結(jié)果為 1；COUNTIF(A1:A4,"=0") 用于統(tǒng)計(jì) A1:A4 中值為 0 的單元格個(gè)數(shù)，結(jié)果為 1；把各部分統(tǒng)計(jì)結(jié)果相減，即 4 - 1 - 1，所以最終統(tǒng)計(jì)結(jié)果為 2。

四、Excel CountA函數(shù)的擴(kuò)展使用實(shí)例

（一）OffSet + CountA函數(shù)組合實(shí)現(xiàn)添加數(shù)據(jù)后自動(dòng)求和

1、假如要實(shí)現(xiàn)在表格最后一行添加銷量后自動(dòng)求和。雙擊 E2 單元格，把公式 =SUM(OFFSET(D1,1,,COUNTA(D:D)-1)) 復(fù)制到 E2，按回車，返回求和結(jié)果 6607；雙擊 D8，輸入 783，按回車，E2 中的值自動(dòng)變?yōu)?7390，說(shuō)明累加了新輸入的 783；操作過(guò)程步驟，如圖8所示：

圖8

2、公式 =SUM(OFFSET(D1,1,,COUNTA(D:D)-1)) 說(shuō)明：

A、COUNTA(D:D) 用于統(tǒng)計(jì) D 列有內(nèi)容的單元格總數(shù)，結(jié)果為 7，正好是 D1:D7 的單元格總數(shù)；再用 7 減 1，結(jié)果為 6。

B、則 OFFSET(D1,1,,COUNTA(D:D)-1) 變?yōu)?OFFSET(D1,1,,6)，接著以 D1 為基準(zhǔn)，返回 D1 下 1 行 0 列且高度為 6 的單元格引用，即對(duì) D2:D7 的引用。

C、則公式變?yōu)?=SUM(D2:D7)，最后用 Sum 對(duì) D2:D7 求和，最終結(jié)果為 6607。當(dāng)在最后一行 D8 輸入 783 后，COUNTA(D:D) 的統(tǒng)計(jì)結(jié)果變?yōu)?8，8 減 1 后變?yōu)?7，則 OffSet 返回 D2:D8，因此在表格后每添加一行，公式都會(huì)把銷量自動(dòng)計(jì)入求和。

（二）If + Mod + CountA + Row函數(shù)組合實(shí)現(xiàn)分段統(tǒng)計(jì)

1、假如要統(tǒng)計(jì)“1月和2月”的銷量個(gè)數(shù)。雙擊 E2 單元格，把公式 =IF(MOD(ROW()-2,4)=0,COUNTA(OFFSET($D$2:$D$5,INT((ROW()-2)/4)*4,)),"") 復(fù)制到 E2，按回車，返回統(tǒng)計(jì)結(jié)果 3；選中 E2，把鼠標(biāo)移到 E2 右下角，鼠標(biāo)變?yōu)榧犹?hào)后，按住左鍵，往下拖一直拖到最后一行，則分別統(tǒng)計(jì)出“1月和2月”的銷量個(gè)數(shù)，操作過(guò)程步驟，如圖9所示：

圖9

2、公式 =IF(MOD(ROW()-2,4)=0,COUNTA(OFFSET($D$2:$D$5,INT((ROW()-2)/4)*4,)),"") 說(shuō)明：

A、公式中的 4 表示一段為四行，ROW() 返回公式所在的行號(hào) 2，則 (ROW()-2)/4 返回 0；Int函數(shù)用于取整，則 INT(0) 返回 0。

B、則 OFFSET($D$2:$D$5,INT((ROW()-2)/4)*4,) 變?yōu)?OFFSET($D$2:$D$5,0*4,)，接著用 OffSet 返回以 D2:D5 左上角的單元格 D2 為基準(zhǔn)、D2 下 0 行 0 列且高度和寬度與 D2:D5 一樣的單元格引用，即返回 D2:D5。

C、則 COUNTA(OFFSET($D$2:$D$5,INT((ROW()-2)/4)*4,)) 變?yōu)?COUNTA($D$2:$D$5)，進(jìn)一步計(jì)算，對(duì) D2:D5 進(jìn)行統(tǒng)計(jì)，結(jié)果為 3。

D、則公式變?yōu)?=IF(MOD(ROW()-2,4)=0,3,"")；由于 ROW() 返回 2，因此 MOD(ROW()-2,4) 變?yōu)?MOD(2-2,4)，接著用Mod函數(shù)把 0 與 4 取模，結(jié)果為 0；則公式變?yōu)?=IF(0=0,3,"")，由于 If 條件 0=0 成立，所以返回 3。

E、當(dāng)公式在 E6 時(shí)，ROW() 返回 6，代入 INT((ROW()-2)/4) 為 INT((6-2)/4)，進(jìn)一步計(jì)算變?yōu)?INT(1)，結(jié)果為 1；則 OFFSET($D$2:$D$5,INT((ROW()-2)/4)*4,) 變?yōu)?OFFSET($D$2:$D$5,1*4,)，接著，返回以 D2:D5 左上角的單元格 D2 為基準(zhǔn)、D2 下 4 行 0 列且高度和寬度與 D2:D5 一樣的單元格引用，即返回 D6:D9，以下的計(jì)算方法跟上面一樣。