Sum函數是 Excel 中用于求和的函數，它最多可以有 256 個參數；參數既可以數字，又可以是單元格的引用、數組、邏輯與能轉為數值的文本；如果引用單元格或數組中含用空單元格或不能轉為數字的文本將被忽略。

　　Sum函數除對參數求和外，還可以與其它函數組合使用，例如與If函數、OffSet函數、Match函數、Left函數、Right函數、Index函數等組合使用；Sum函數與If函數組合最常見，用于求滿足指定條件的和；Sum函數與OffSet函數、Match函數組合，可用于動態求和。

　　一、Excel Sum函數語法

　　1、表達式：SUM(Number1, [Number2], ...)

　　中文表達式：求和（數字1，[數字2]）

　　2、說明：

　　A、Sum函數至少要有一個數字，最多只能有 256 個數字。

　　B、參數 Number 可以是數字外，還可以是對單元格區域的引用、數組、邏輯值（True 或 False）。如果引用單元格區域或數組中有文本，能轉為數值的自動把它轉為數值并計入求和，不能轉數值的忽略。如果引用單元格區域或數組中有邏輯值，它們將被忽略；如果直接把邏輯值作為獨立參數寫到Sum函數中，True 被計入 1，False 被計入 0。不能轉為數值的文本不能作為獨立的參數寫到Sum函數中。

　　二、Excel Sum函數基本使用實例

　　（一）參數為數字的實例

　　1、選中 A1 單元格，輸入公式 =SUM(2,6,18)，按回車，返回求和結果 26；操作過程步驟，如圖1所示：

圖1

　　2、公式 =SUM(2,6,18) 共有三個參數，Sum函數把它們相加，即 2 + 6 + 18 = 26。

　　（二）參數為引用單元格區域的實例

　　1、選中 B1 單元格，把公式 =SUM(A1,A2,A3) 復制到 B1，按回車，返回 21；雙擊 B2，把公式改為 =SUM(A1:A3)，按回車，同樣返回 21；再次雙擊 B1，把公式改為 =SUM(21,True)，按回車，返回 22；雙擊 B1，在 True 后添加 False，按回車，仍然返回 22；雙擊 B1，把公式改為 =SUM(21,True,"Sum函數")，按回車，返回錯誤值 #VALUE!；操作過程步驟，如圖2所示：

圖2

　　2、Sum函數引用單元格時，既可以一個個寫，又可以合在一起寫（前提是單元格連續）；一個個寫的如 =SUM(A1,A2,A3)，連續寫的如=SUM(A1:A3)。

　　3、Sum函數引用單元格中有邏輯值和文本時，邏輯值和文本都被忽略，如 =SUM(A1:A3) 返回求和結果 21；當把邏輯值寫到 Sum 中作為獨立參數時，True 算 1，如 =SUM(21,True) 返回求和結果 22，False 算 0，如 =SUM(21,True,False) 返回求和結果 22。當把文本寫到 Sum 中作為獨立參數時，直接返回值錯誤 #VALUE!。

　　（三）參數為數組的實例

　　1、選中 A1 單元格，把公式 =SUM({3,8,15}) 復制到 A1，按回車，返回 26；雙擊 A1，把公式改為 =SUM({3,8,15,True})，按回車，同樣返回 26；再雙擊 A1，把公式改為 =SUM({3,8,15,True,false})，按回車，仍然返回 26；雙擊 A1，把公式改為 =SUM({3,8,15,True,"Sum函數"})，按回車，也返回 26；操作過程步驟，如圖3所示：

圖3

　　2、當Sum函數的參數為數組時，文本和邏輯值都被忽略，如演示中的 True、False 和 "Sum函數" 都沒有計入求和。

　　三、Excel Sum函數與其它函數的組合使用實例

　　（一）Sum + If函數

　　1、假如要求所有女裝的銷量之和。選中 F11 單元格，把公式 =SUM(IF(C2:C10="女裝",F2:F10,0)) 復制到 F11 單元格，按 Ctrl + Shift + 回車，返回求和結果 4284；操作過程步驟，如圖4所示：

圖4

　　2、公式說明：

　　A、公式 =SUM(IF(C2:C10="女裝",F2:F10,0)) 是一個數組公式，因此要按 Ctrl + Shift + 回車。

　　B、IF(C2:C10="女裝",F2:F10,0) 的條件 C2:C10="女裝" 返回一個數組；執行時，第一次從 C2 到 C10 中取 C2，如果為“女裝”，則返回 F2 至 F10 中的 F2（即返回 329），否則返回 0；第二次取 C3，如果為“女裝”，返回 F3（即返回 569），否則返回 0；按照這樣的順序一直取到 C10，最返回數組 {329,569,638,0,528,563,0,765,892}。

　　C、則公式變為 =SUM({329,569,638,0,528,563,0,765,892})，最后用 Sum 求和，所以返回 4284。

　　提示：如果求和區域超過一列，只要它們連續，也可以把它們寫在一起作為 If 的條件；假如要在 C 列到 E 列求分類為“女裝”的銷量之和，公式可以這樣寫： =SUM(IF(C2:E10="女裝",F2:F10,0))。

　　（二）Sum + Right函數

　　1、假如要計算服裝表中所有T恤的銷量之和。選中 F11 單元格，把公式 =SUM((RIGHT(B$2:B$10,2)="T恤")*(F$2:F$10)) 復制到 F11，按Ctrl + Shift + 回車，返回求和結果 3482；操作過程步驟，如圖5所示：

圖5

　　2、公式說明：

　　A、公式中 B$2:B$10 用于以數組形式返回 B2 至 B10 的“產品名稱”，B$2 表示對列相對引用、對行絕對引用，即往下拖時，列不變行變，如 B2 會變為 B3、B4、……；B$10 與 B$2 一樣。F$2:F$10 用于以數組形式返回 F2 至 F10 的“銷量”。

　　B、Right函數用于從右邊截取字符，RIGHT(B$2:B$10,2) 用于從右邊截取 B 列“產品名稱”的兩個字符；當公式執行時，第一次從 B2 至B10 中取出 B2（即“長袖白襯衫”），然后從右邊開始截取兩個字符，即截取“襯衫”；第二次取出 B2 并從右邊截取兩個字符，一直取到B10，最后返回數組{"襯衫";"T恤";"T恤";"襯衫";"T恤";"襯衫";"T恤";"T恤";""襯衫"}。

　　C、則 RIGHT(B$2:B$10,2)="T恤" 變為 {"襯衫";"T恤";"T恤";"襯衫";"T恤";"襯衫";"T恤";"T恤";""襯衫"}="T恤"，接著從數組左邊開始位次取出每一個元素，并與“T恤”比較，如果等于“T恤”，返回 True，否則返回 False，最終返回數組 {False;True;True;False;True;False;True;True;"False}。

　　D、F$2:F$10 返回數組 {329,569,638,897,528,563,982,765,892}，則公式變為
=SUM(({False;True;True;False;True;False;True;True;False})*({329,569,638,897,528,563,982,765,892}))。

　　E、接著，把兩個數組對應的元素相乘，相乘時 True 被轉為 1，False 被轉為 0，則公式變為 =SUM({0;569;638;0;528;0;982;765;0}),最后用 Sum 求和返回 3482。

　　（三）Sum + OffSet + Match函數

　　1、假如要根據任意月份計算各類服裝當月的銷量和。選中 B12 單元格，把公式 =SUM(OFFSET(B1,MATCH(A12,A$2:A$9,0),,1,4)) 復制到B12，按回車，返回“1月”各類服裝的銷量之和；雙擊 A12 單元格，把“1月”改為“2月”，單擊 B12，返回“2月”各類服裝的銷量之和；再把“3月”改為“8月”，則返回“8月”的各類服裝銷量之和；操作過程步驟，如圖6所示：

圖6

　　2、公式說明：

　　A、MATCH(A12,A$2:A$9,0) 用于返回 A12 在 A2 至 A9 中的位置，例如 A12 為“1月”，則返回的位置為 1（以 A2 為起始），第三個參數 0 表示精確匹配，即 A2 至 A9 中數據要等于“1月”。

　　B、OFFSET(B1,MATCH(A12,A$2:A$9,0),,1,4) 變為 OFFSET(B1,1,,1,4)，OffSet 中，B1 為基準單元格，第二個參數 1 為行號，第三個參數為列號（省略了），第四個參數 1 為返回引用單元格區域的行高，第五個參數 4 為返回引用單元格區域的列寬；由于行號為正，因此返回B1 下面的單元格區域，又因為行號為 1，所以返回 B1 下邊的一行（即第二行）；又因為省略了列號，且要返回的單元格區域行高為1、列寬為 4，因此返回 B2:E2。

　　C、則公式變為 =SUM(B2:E2)，再用 Sum 求和，最后返回 1614；當 A12 為其它月份時也是一樣的道理。